Examples

Notebooks

In the folder notebooks several notebooks, using Pluto.jl, for the simulation of GC-systems are available.

To use these notebooks Julia, v1.6 or above, must be installed and Pluto must be added:

julia> ]
(v1.7) pkg> add Pluto

To run Pluto, use the following commands:

julia> using Pluto
julia> Pluto.run()

Pluto will open your browser. In the field Open from file the URL of a notebook or the path to a locally downloaded notebook can be insert and the notebook will open and load the necessary packages.

Overview of notebooks

• simulation_conventional_GC.jl - Simulation of a conventional GC-system (constant temperature, constant diameter and constant film thickness along the column) and outlet pressure as "vacuum" or "atmospheric", with option of flow or pressure control and temperature program notation in the typical form used in commercial GC software (temperature levels, holding times and heating ramps). Results can be exported.
• simulation_conventional_GC_TL.jl - Simulation of a conventional GC-system (constant temperature, constant diameter and constant film thickness along the column) with an attached transfer line (at a fixed temperature) and outlet pressure as "vacuum" or "atmospheric", with option of flow or pressure control and temperature program notation in the typical form used in commercial GC software (temperature levels, holding times and heating ramps). Results can be exported.
• simulation_conventional_GC_load_2dbs.jl - Simulation of a conventional GC-system (constant temperature, constant diameter and constant film thickness along the column) and loading of up to two different substance databases and simulation of the common substances with the same GC-system and comparing the result. Also, an option is given, to load measured retention times and compare these to the simulations. Same setting for programs as in simulation_conventional_GC.jl
• simulation_example.jl - General example of simulation of a GC-system with optional thermal gradient (exponential/linear model of temperature change along the column) and constant diameter and constant film thickness along the column. Results can be exported.
• simulation_example_input_gradient_function.jl - Simulation of a GC-system with optional thermal gradient where the temperature change along the column is defined by a user-defined equation (cosine-function as example).

Simulation of measurements

Two measurements from [8] will be simulated and compared to the measured chromatograms. The n-alkanes from n-nonane (C9) to n-triacontane (C30) are separated in a conventional GC and a thermal gradient GC . The database with the thermodynamic parameters is Database_Leppert2020b.csv.

Conventional GC

The conventional GC program simulated here is Prog. D from [8], a temperature program with two heating ramps, constant inlet pressure and a flame ionization detector (FID, atmospheric outlet pressure).

The standard options are used, beside the option ng (non-gradient) is changed to true. Because the conventional GC does not use non-uniform temperature, diameter or film thickness, the model can be simplified and the calculation of the separation is faster.

opt = GasChromatographySimulator.Options(ng=true)

GasChromatographySimulator.Options(OwrenZen5{typeof(OrdinaryDiffEqCore.trivial_limiter!), typeof(OrdinaryDiffEqCore.trivial_limiter!), Static.False}(OrdinaryDiffEqCore.trivial_limiter!, OrdinaryDiffEqCore.trivial_limiter!, static(false)), 1.0e-6, 0.001, "inlet", true, true, "Blumberg", "Pressure", 1.0e12)

The column has a length of 11.18 m, a diameter of 0.104 mm and a film thickness of 0.104 µm. The stationary phase is labeled as FS5ms and the mobile phase gas is helium:

col = GasChromatographySimulator.Column(11.18, 0.104e-3, 0.104e-6, "FS5ms", "H2");

GasChromatographySimulator.Column(11.18, 0.000104, [0.000104], 1.04e-7, [1.04e-7], "FS5ms", "H2")

The temperature program starts at 40°C, which is hold for 1 min. The column is heated up to 180°C in 28 min (5°C/min heating ramp), where the temperature is also hold for 1min. Than the column is heated to 300°C in 6 min (20°C/min heating ramp), where the temperature again is kept for 1 min. The inlet pressure is at constant 411564 Pa (absolute) and the outlet pressure is at constant 101300 Pa (absolute) during the program.

prog_D = GasChromatographySimulator.Program([0.0, 60.0, 1680.0, 60.0, 360.0, 60.0], [40.0, 40.0, 180.0, 180.0, 300.0, 300.0], 411564.0*ones(6), 101300.0.*ones(6), col.L);

We want to use all solutes for the stationary phase FS5ms, which are in the database Database_Leppert2020b.csv. We load the database into a dataframe:

db_dataframe = DataFrame(CSV.File("../../data/Leppert2020b/Database_Leppert2020b.csv", header=1, silencewarnings=true));

and extract all the names of the substances with:

solutes = GasChromatographySimulator.all_solutes(col.sp, db_dataframe);

22-element Vector{InlineStrings.String3}:
 "C9"
 "C10"
 "C11"
 "C12"
 "C13"
 "C14"
 "C15"
 "C16"
 "C17"
 "C18"
 ⋮
 "C22"
 "C23"
 "C24"
 "C25"
 "C26"
 "C27"
 "C28"
 "C29"
 "C30"

The injection is assumed to be ideal with initial peak widths τ₀ of 0 seconds and occuring at the beginning of the temperature program (t₀ of 0 seconds). The data for all solutes is finally loaded with:

t₀ = zeros(length(solutes))
τ₀ = zeros(length(solutes))
sub = GasChromatographySimulator.load_solute_database(db_dataframe, col.sp, col.gas, solutes, t₀, τ₀)

The parameters are combined:

par = GasChromatographySimulator.Parameters(col, prog_D, sub, opt);
nothing # hide

The temperature program and the pressure/flow program can be plotted:

p_flow = GasChromatographySimulator.plot_flow(par)
p_press = GasChromatographySimulator.plot_pressure(par)
p_temp = GasChromatographySimulator.plot_temperature(par)
l = @layout([a{0.65w} [b; c]])
p_TpF = plot(p_temp, p_press, p_flow, layout=l)

The temperatures at the column inlet and outlet are identical, the temperature along the colum is uniform. With the temperature program and the constant pressures, the flow decreases during the temperature program.

Finally, the simulation is executed:

peaklist, sol = GasChromatographySimulator.simulate(par);
nothing # hide

with the peaklist:

peaklist # hide

We know can compare the simulation results with the measured chromatogram. The file Leppert2020b_measured_RT_progD.csv contains the retention times and peak widths (as standard deviations) from the measurement.

measurement_D = DataFrame(CSV.File("../../data/Leppert2020b/Leppert2020b_measured_RT_progD.csv", header=1, silencewarnings=true));
measurement_D[!, 2] = measurement_D[!, 2] .* 60.0; # conversion from min -> s
rename!(measurement_D, [:Name, :tR, :τR]);

The simulated and measured separations can be compared by comparing the peak lists:

compare = GasChromatographySimulator.compare_peaklist(measurement_D, peaklist)

Differences between measured and simulated retention times are in the range of some seconds, while the retention times are in minutes. Most differences are below 1%. The measured peak widths are 10 to 15% higher than the calculated peak widths.

The measured and simulated separation can also be compared by a plot of the chromatograms:

chrom_D = DataFrame(CSV.File("../../data/Leppert2020b/Leppert2020b_measured_Chrom_progD.csv", header=1, silencewarnings=true))
p_chrom, t, chrom = GasChromatographySimulator.plot_chromatogram(peaklist, (0.0, round(chrom_D[end,1];sigdigits=2)); annotation=false, number=true, mirror=true, offset=0.0)
plot!(p_chrom, chrom_D[!,1], chrom_D[!,2].*400.0.+0.1)
ylims!(-1.6,1.6)
xlims!(0.0,round(chrom_D[end,1];sigdigits=2))
p_chrom

The measured chromatogram is plotted in orange, while the simulated chromatogram is plotted in blue and mirrored.

Thermal gradient GC

The following example of a thermal gradient GC is the example medium gradient from [8].

Standard options are used (here the option ng has to be false):

opt_tg = GasChromatographySimulator.Options()

GasChromatographySimulator.Options(OwrenZen5{typeof(OrdinaryDiffEqCore.trivial_limiter!), typeof(OrdinaryDiffEqCore.trivial_limiter!), Static.False}(OrdinaryDiffEqCore.trivial_limiter!, OrdinaryDiffEqCore.trivial_limiter!, static(false)), 1.0e-6, 0.001, "inlet", true, false, "Blumberg", "Pressure", 1.0e12)

And the column is 2.05 m long and has the same diameter, film thickness and stationary phase as in the example before. Here Helium is used as mobile phase.

col_tg = GasChromatographySimulator.Column(2.05, 0.104e-3, 0.104e-6, "FS5ms", "He");

GasChromatographySimulator.Column(2.05, 0.000104, [0.000104], 1.04e-7, [1.04e-7], "FS5ms", "He")

The program is taken from the measured temperatures and pressures during the GC run, stored in the file Leppert2020b_prog_settings_med_gradient_x90.csv.

prog_settings = DataFrame(CSV.File("../../data/Leppert2020b/Leppert2020b_prog_settings_med_gradient_x90.csv", header=1, silencewarnings=true));